FastReport VCL是用于 Delphi、C++ Builder、RAD Studio 和 Lazarus 的报告和文档创建 VCL 库。它提供了可视化模板设计器,可以访问 30 多种格式,并可以部署到云、网站、电子邮件和打印中。
立即点击下载FastReport VCL v6.9最新版
FastReport 有大量的组件,可以放在报表设计页面上。它们是:文本、图片、线条、几何图形、OLE、Rich、条码、图表等。您也可以编写自己的自定义组件,然后将其附加到FastReport。
在 FastReport 中定义了几个类,从中继承了组件。有关更多详细信息,请参阅“ FastReport 类层次结构”一章。这个TfrxView类是我们最感兴趣的,因为大多数报表组件都是从它继承而来的。
至少应该有基本类中Draw定义的方法TfrxReportComponent。
procedure Draw(Canvas: TCanvas; ScaleX, ScaleY, OffsetX, OffsetY: Extended); virtual;
在设计器中、预览窗口中和输出打印期间绘制组件时调用此方法。TfrxView覆盖此方法以绘制对象框架和背景。此方法应该在“Canvas”绘图表面上绘制组件内容。对象坐标和大小都存储在AbsLeft,AbsTop,Width和Height相应属性。
ScaleX 和 ScaleY 参数分别定义 X 轴和 Y 轴上的对象缩放。这些参数在 100% 缩放时等于 1,如果用户在设计器或预览窗口中修改缩放,则这些参数可能会有所不同。OffsetX 和 OffsetY 参数通过 X 轴和 Y 轴进行点位移。因此,当考虑这些参数时,左上角坐标如下:
X := Round(AbsLeft * ScaleX + OffsetX);
为了简化坐标操作,在类中定义了BeginDraw方法(其参数类似于Draw方法)TfrxView
procedure BeginDraw(Canvas: TCanvas; ScaleX, ScaleY, OffsetX, OffsetY: Extended); virtual;
它应该在Draw方法的第一行中调用。此方法将坐标转换为FX, , FY, FX1, FY1, FDX, FDY,FFrameWidth整数值,以后可以在 TCanvas 方法中使用。此方法还将 Canvas、ScaleX 和 ScaleY 值复制到FCanvas、FScaleX、FScaleY变量中,可以从任何类方法中引用这些变量。
还有两种为TfrxView类中的对象绘制背景和框架的方法。
procedure DrawBackground;procedure DrawFrame;
BeginDraw 方法应该在调用这些方法之前被调用。
让我们检查创建一个将显示箭头的组件。
type
TfrxArrowView = class(TfrxView)
public
{ we should override only two methods }
procedure Draw(Canvas: TCanvas; ScaleX, ScaleY, OffsetX, OffsetY: Extended); override;
class function GetDescription: String; override;
published
{ Place required properties into the published section }
property BrushStyle;
property Color;
property Frame;
end;
class function TfrxArrowView.GetDescription: String;
begin
{ component description will be displayed next to its icon in toolbar }
Result := ‘Arrow object’;
end;
procedure TfrxArrowView.Draw(Canvas: TCanvas; ScaleX, ScaleY, OffsetX, OffsetY: Extended);
begin
{ call this method to perform coordinates transformation }
BeginDraw(Canvas, ScaleX, ScaleY, OffsetX, OffsetY);
with Canvas do
begin
{ set colors }
Brush.Color := Color;
Brush.Style := BrushStyle;
Pen.Width := FFrameWidth;
Pen.Color := Frame.Color;
{ draw arrow }
Polygon(
[Point(FX, FY + FDY div 4),
Point(FX + FDX * 38 div 60, FY + FDY div 4),
Point(FX + FDX * 38 div 60, FY),
Point(FX1, FY + FDY div 2),
Point(FX + FDX * 38 div 60, FY1),
Point(FX + FDX * 38 div 60, FY + FDY * 3 div 4),
Point(FX, FY + FDY * 3 div 4)]);
end;
end;
{ registration }
var
Bmp: TBitmap;
initialization
Bmp := TBitmap.Create;
Bmp.LoadFromResourceName(hInstance, ‘frxArrowView’);
frxObjects.RegisterObject(TfrxArrowView, Bmp);
finalization
{ delete component from list of available ones }
frxObjects.Unregister(TfrxArrowView);
Bmp.Free;
end.
创建其显示从一个DB之一的任何数据传输应的组件DataSet,DataField属性分为“发布”部分,然后重写GetData方法。让我们以TfrxCheckBoxView标准组件为例对其进行检查。
该组件可以通过基本类中声明的DataSet和DataField属性连接到 DB 字段TfrxView。此外,该组件具有Expression可放置表达式的属性。一旦计算出来,结果将被放入Checked属性中。如果Checked属性等于“True” ,则此组件显示一个叉号。您可以在下方看到组件的初始声明文本(最重要的部分)。
TfrxCheckBoxView = class(TfrxView)
private
FChecked: Boolean;
FExpression: String;
procedure DrawCheck(ARect: TRect);
public
procedure Draw(Canvas: TCanvas; ScaleX, ScaleY, OffsetX, OffsetY: Extended); override;
procedure GetData; override;
published
property Checked: Boolean read FChecked write FChecked default True;
property DataField;
property DataSet;
property Expression: String read FExpression write FExpression;
end;
procedure TfrxCheckBoxView.Draw(Canvas: TCanvas; ScaleX, ScaleY, OffsetX, OffsetY: Extended);
begin
BeginDraw(Canvas, ScaleX, ScaleY, OffsetX, OffsetY);
DrawBackground;
DrawCheck(Rect(FX, FY, FX1, FY1));
DrawFrame;
end;
procedure TfrxCheckBoxView.GetData;
begin
inherited;
if IsDataField then
FChecked := DataSet.Value[DataField]
else if FExpression <> ‘’ then
FChecked := Report.Calc(FExpression);
end;
如果您对 FastReport 感兴趣,欢迎加入 FastReport QQ 交流群:702295239